(* 2019年度の宿題の検算 *)

(* 問1 (1) の検算をしてみる *)

z1=4-3I

z2=2+I

z1+z2

z1-z2

z1 z2

z1/z2

Abs[z1]

Re[z1]

Im[z1]

Conjugate[z1]

(* 問1(2) これはあまりすっきり解けない *)
sol=Solve[z^2==2-3I,z]

sol2=Solve[{x^2-y^2==2,2x y==-3},{x,y},Reals]

ToRadicals[sol2]

(* 問2 極形式を求めよ → 絶対値 |z| と偏角 arg z を求めよ *)

z=-Sqrt[3]-3I

Abs[z]

Arg[z]

(* 問3 1 と -1 の n乗根 *)

Clear[z]

Solve[z^3==I,z]

ComplexExpand[%]

Solve[z^6==1,z]

ComplexExpand[%]

Solve[z^6==-1,z]

ComplexExpand[%]

(* 問4 正則関数の実部虚部, Cauchy-Riemann 方程式 *)

f[z_]:=1/z^2

(* ComplexExpand[] という関数を使うと良い *)

ComplexExpand[f[x+y I]]

u[x_,y_]:=Simplify[ComplexExpand[Re[f[x+y I]]]]

v[x_,y_]:=Simplify[ComplexExpand[Im[f[x+y I]]]]

u[x,y]

v[x,y]

(* u についてはゆっくり *)

{D[u[x,y],x],D[u[x,y],y]}

Simplify[%]

(* v の方は一気にやってみる *)

Simplify[D[v[x,y],{{x,y}}]]

f[z_]:=(Exp[I z]-Exp[-I z])/(2I)

u[x_,y_]:=Simplify[ComplexExpand[Re[f[x+y I]]]]

v[x_,y_]:=Simplify[ComplexExpand[Im[f[x+y I]]]]

{u[x,y],v[x,y]}

Simplify[D[u[x,y],{{x,y}}]]

Simplify[D[v[x,y],{{x,y}}]]

(* 問6 無限級数に展開する関数はないが、一般項を求める SeriesCoefficient[] がある。有限項までの展開ならば Series[] でできる。 逆に級数の和を Sum[] で計算して元と同じかチェックできる *)
(* (1)(a) *)
f[z_]:=1/(4-z)

Series[f[z],{z,0,10}]

SeriesCoefficient[f[z],{z,0,n}]

Sum[z^n/4^(n+1),{n,0,Infinity}]

(* (b) *)

g[z_]:=4/(2z+3)

SeriesCoefficient[g[z],{z,0,n}]

Sum[4(-2)^n/3^(n+1)z^n,{n,0,Infinity}]

(* (c) *)

h[z_]:=1/(z-I)^2

SeriesCoefficient[h[z],{z,0,n}]

Sum[(-1)^(n+1) I^n(n+1)z^n,{n,0,Infinity}]

(* (d) *)
1+Sum[z^n/(4^n n),{n,1,Infinity}]

D[%,z]

(* (2) *)

F[z_]:=1/(4-z)

SeriesCoefficient[F[z],{z,-3,n}]

Sum[(z+3)^n/7^(n+1),{n,0,Infinity}]

(* 問7 (1) *)
f[z_]:=(-z^3+3z^2+8z+14)/(z^2-2z-8)

Apart[f[z]]

SeriesCoefficient[f[z],{z,1,n}]

f[1]

-8/3+-11(z-1)/9+Sum[-(5+3(-1)^n)/3^(n+1)(z-1)^n,{n,2,Infinity}]

Together[%]

(* Abelの連続性定理に現われる集合 *)
stolz[K_,R_]:=Block[{g1,g2},g1=ContourPlot[x^2+y^2==R^2,{x,-2 R,2 R},{y,-2 R,2 R}];
g2=RegionPlot[x^2+y^2<R^2&&Abs[1-(x+I y)/R]/(1-Abs[x+I y]/R)≤K,{x,-2 R,2 R},{y,-2 R,2 R}];Show[g1,g2]]

R=1
Manipulate[stolz[K,R],{K,1,10,0.1}]

(* 複素対数関数を描こう *)

Plot3D[Boole[x^2+y^2<4] Im[Log[x+I y]],{x,-2,2},{y,-2,2}]

Plot3D[Boole[x^2+y^2<4] Re[Log[x+I y]],{x,-2,2},{y,-2,2}]

ContourPlot[Im[Log[x+I y]],{x,-2,2},{y,-2,2},Contours->Table[x,{x,-Pi,Pi,Pi/8}]]

ContourPlot[Re[Log[x+I y]],{x,-2,2},{y,-2,2}]